Delphi - Convert email to HTML

The following delphi codes demonstrate how to convert email to a HTML page and display it using Web browser Control.

After the email was converted to HTML page, you can browse it with web browser. You can get everything in the HTML page such as From, To, Cc, Subject, Date, Attachments and Embedded images.

Installation

Before you can use the following sample codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Add reference

To better demonstrate how to retrieve email and parse email, let’s create a Delphi Standard EXE project at first, then add a TButton on the Form, double-click this button. It is like this:

Delphi console project

To use EAGetMail ActiveX Object in your Delphi project, the first step is “Add Unit file of EAGetMail to your project”. Please go to C:\Program Files\EAGetMail\Include\delphi or C:\Program Files (x86)\EAGetMail\Include\delphi folder, find EAGetMailObjLib_TLB.pas, and then copy this file to your project folder.

// include EAGetMailObjLib_TLB unit to your Delphi Project
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, EAGetMailObjLib_TLB, StdCtrls;

Then you can start to use it in your Delphi Project.

You can also create EAGetMailObjLib_TLB.pas manually by Delphi like this:

  • Delphi 7 or eariler version

    First of all, create a standard delphi project: select menu Project -> Import Type Library, checked EAGetMail ActiveX Object and click Create Unit. Then include EAGetMailObjLib_TLB in your project.

    add reference in Delphi
  • Delphi XE or later version

    First of all, create a standard delphi project: select menu Component -> Import component... -> Import a type library -> checked EAGetMail ActiveX Object, have Generate Component Wrapper checked and click “Create Unit”. Then include EAGetMailObjLib_TLB in your project.

Delphi - Parse and convert email to HTML - example

The following example codes demonstrate converting email to HTML page. In order to run it correctly, please change email server, user, password, folder, file name value to yours.

Note

To get full sample projects, please download and install EAGetMail on your machine.

unit Unit1;

interface

uses
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
    Dialogs, StdCtrls, StrUtils, EAGetMailObjLib_TLB;

type
    TForm1 = class(TForm)
        Button1: TButton;
        procedure Button1Click(Sender: TObject);
    private
        { Private declarations }
        procedure ConvertMailToHtml(fileName: WideString);
        procedure GenerateHtmlForEmail(emlFile: WideString; htmlFile: WideString; attachmentFolder: WideString);
        function FormatAddresses(addresses: IAddressCollection; prefix: WideString): WideString;
    public
        { Public declarations }
    end;

const
    CRYPT_MACHINE_KEYSET = 32;
    CRYPT_USER_KEYSET = 4096;
    CERT_SYSTEM_STORE_CURRENT_USER = 65536;
    CERT_SYSTEM_STORE_LOCAL_MACHINE = 131072;

Var
    Form1: TForm1;

Implementation

{$R *.dfm}

procedure TForm1.ConvertMailToHtml(fileName: WideString);
var
    htmlFile, attachmentFolder: WideString;
    oTools: TTools;
begin
    // Remove .eml extension
    htmlFile := LeftStr(fileName, length(fileName) - 4) + '.htm';
    attachmentFolder := LeftStr(fileName, length(fileName) - 4);

    oTools := TTools.Create(Application);
    if not oTools.ExistFile(htmlFile) then
        begin
            // We haven't generate the html for this email, generate it now.
            GenerateHtmlForEmail(fileName, htmlFile, attachmentFolder);
        end;

end;

procedure TForm1.GenerateHtmlForEmail(emlFile: WideString; htmlFile: WideString; attachmentFolder: WideString);
var
    oMail: TMail;
    oTools: TTools;
    attachments: IAttachmentCollection;
    oAttachment: IAttachment;
    i: integer;
    html, header, attachmentName: WideString;
begin
    oTools := TTools.Create(Application);
    oMail := TMail.Create(Application);
    oMail.LicenseCode := 'TryIt';

    oMail.LoadFile(emlFile, false);

    try
        if oMail.IsEncrypted then
            oMail.Load(oMail.Decrypt(nil).Content);
    except
        on ep:Exception do
            ShowMessage('Decrypt Error: ' + ep.Message);
    end;

    try
        if oMail.IsSigned then
            oMail.VerifySignature();
    except
        on ep:Exception do
            ShowMessage('Verify Digital Signature Error: ' + ep.Message);
    end;

    // Decode winmail.dat (TNEF stream) automatically.
    // also convert RTF body to HTML automatically.
    oMail.DecodeTNEF();

    html := oMail.HtmlBody;
    header := header + '<font face="Courier New,Arial" size="2">';
    header := header + '<b>From:</b> ' + oMail.From.Name + ' &lt;' + oMail.From.Address + '&gt;' + '<br>';

    header := header + FormatAddresses(oMail.ToList, 'To');
    header := header + FormatAddresses(oMail.CcList, 'Cc');
    header := header + '<b>Subject:</b>' + oMail.Subject + '<br>' + #13#10;

    // Parse attachment
    attachments := oMail.AttachmentList;
    if(attachments.Count > 0) then
        begin
            // Create a temporal folder to store attachments.
            if not oTools.ExistFile(attachmentFolder) then
                oTools.CreateFolder(attachmentFolder);

            header := header + '<b>Attachments:</b> ';
            for i:= 0 to attachments.Count - 1 do
                begin
                    oAttachment := attachments.Item[i];

                    attachmentName := attachmentFolder + '\' + oAttachment.Name;
                    oAttachment.SaveAs(attachmentName, true);
                    header := header + '<a href="' + attachmentName + '" target="_blank">' + oAttachment.Name + '</a> ';

                        // Show embedded images
                    if oAttachment.ContentID <> '' then
                        begin
                            // StringReplace doesn't support some non-ascii characters very well.
                            html := StringReplace(html, 'cid:' + oAttachment.ContentID, attachmentName, [rfReplaceAll, rfIgnoreCase]);
                        end
                end;
        end;

    header := '<meta http-equiv="Content-Type" content="text-html; charset=utf-8">' + header;
    html := header + '<hr>' + html;
    oTools.WriteTextFile(htmlFile, html, 65001);

end;

function TForm1.FormatAddresses(addresses: IAddressCollection; prefix: WideString): WideString;
var
    value: WideString;
    i: integer;
begin
    if addresses.Count = 0 then
    begin
        result := '';
        exit;
    end;

    value := '<b>' + prefix + ':</b> '; // To or Cc

    for i := 0 to addresses.Count - 1 do
        begin
            if(addresses.Item[i].Name = '') then
            value := value + '&lt;' + addresses.Item[i].Address + '&gt;'
            else
            value := value + addresses.Item[i].Name + ' &lt;' + addresses.Item[i].Address + '&gt;';

            if (i < addresses.Count - 1) then
                value := value + '; ';
        end;

    result := value + '<br>';
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
    try
        ConvertMailToHtml('c:\my folder\test.eml');
    except
        on ep:Exception do
            ShowMessage('Error: ' + ep.Message);
    end;

end;

end.

32bit/x64 ActiveX DLL

Seperate builds of run-time dll for 32 and x64 platform

File Platform
Installation Path\Lib\native\x86\EAGetMailObj.dll 32 bit
Installation Path\Lib\native\x64\EAGetMailObj.dll 64 bit

Distribution

  • Standard EXE

    For VB6, C++, Delphi or other standard exe application, you can distribute EAGetMailObj.dll with your application to target machine without COM-registration and installer. To learn more detail, please have a look at Registration-free COM with Manifest File.

  • Script

    For ASP, VBScript, VBA, MS SQL Stored Procedure, you need to install EAGetMail on target machine by EAGetMail installer, both 32bit/x64 DLL are installed and registered.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.