VB6 - Mark email as read in POP3/IMAP4/EWS/WebDAV

If you want to leave a copy of email on the server, you should not call Delete method. However, there is a problem, how can you know if the email has already been downloaded (read)? If there is a way to identify the downloaded email, you can avoid downloading the duplicated email from your POP3/IMAP4 server.

Every email has a unique identifier (UIDL) on POP3 server. POP3 UIDL is only unique in the email life time. That means if the email was deleted from the server, other email can use the old unique identifier. Another problem is: UIDL in POP3 server can be any number or characters, so we cannot use UIDL as the file name, because UIDL may contain invalid characters for file name.

To solve this problem, we have to store the UIDL to a txt file and synchronize it with server every time.

The following vb6 example codes demonstrate how to mark the email as downloaded/read on POP3 server.

Installation

Before you can use the following sample codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Add reference

To use EAGetMail POP3 & IMAP4 ActiveX Object in your project, the first step is Add reference of EAGetMail to your project. Please go to menu -> Project -> References -> and select EAGetMailObj ActiveX Object, click OK, the reference will be added to your project, and you can start to use it to retrieve email and parse email in your project.

add reference in VB6

Add reference in VBA (EXCEL/Access/Outlook)

Open VBA IDE by press Alt+F11, Please select menu -> Tools -> References -> and select EASendMailObj ActiveX Object, click OK, the reference will be added to current VBA project, and you can start to use it to retrieve email and parse email in your VBA project.

To better demonstrate how to retrieve email and parse email, let’s create a VB 6.0 Standard EXE project at first, then add a CommandButton on the Form, double-click this button. It is like this

VB 6.0 standard project

VB6 - Mark email as read in POP3 - example

The following example codes demonstrate marking email as read/downloaded on POP3 server. In order to run it correctly, please change email server, user, password, folder, file name value to yours.

Note

To get full sample projects, please download and install EAGetMail on your machine.

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3
Const MailServerMsGraph = 4


Private oTools As New EAGetMailObjLib.Tools

Private Sub Command1_Click()
    Dim currentPath As String
    Dim localInbox As String
    Dim isUidlLoaded As Boolean

    isUidlLoaded = False

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    currentPath = App.Path
    localInbox = currentPath & "\inbox"

    oTools.CreateFolder localInbox

    Dim oServer As New EAGetMailObjLib.MailServer
    oServer.Server = "pop3.emailarchitect.net"
    oServer.User = "test@emailarchitect.net"
    oServer.Password = "testpassword"
    oServer.Protocol = MailServerPop3

    ' Enable SSL/TLS connection, most modern email servers require SSL/TLS by default
    oServer.SSLConnection = True
    oServer.Port = 995

    ' If your POP3 doesn't deploy SSL connection
    ' Please use
    ' oServer.SSLConnection = False
    ' oServer.Port = 110

On Error GoTo ErrorHandle:
    Dim leaveCopy As Boolean
    leaveCopy = True

    ' uidl is the identifier of every email on POP3/IMAP4 server, to avoid retrieve
    ' the same email from server more than once, we record the email uidl retrieved every time
    ' if you delete the email from server every time and not to leave a copy of email on
    ' the server, then please remove all the function about uidl.
    ' If you want to re-download all emails, please delete uidl.txt from local inbox.
    Dim oUIDLManager As New EAGetMailObjLib.UIDLManager
    oUIDLManager.Load localInbox & "\uidl.txt"
    isUidlLoaded = True

    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    Dim infos As EAGetMailObjLib.MailInfoCollection
    Set infos = oClient.GetMailInfoList()

    MsgBox infos.Count & " emails"

    ' Remove the local uidl that is not existed on the server,
    oUIDLManager.SyncUIDLEX oServer, infos
    ' Update result back to uidl file
    oUIDLManager.Update

    Dim i As Long
    For i = 0 To infos.Count - 1

        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos.Item(i)

        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        Dim oUIDLItem As UIDLItem
        Set oUIDLItem = oUIDLManager.FindUIDL(oServer, info.UIDL)

        ' If this email has not been retrieved before, then get it
        If oUIDLItem Is Nothing Then

            Dim fileName As String
            fileName = oTools.GenFileName(i) & ".eml"

            Dim fullFileName As String
            fullFileName = localInbox & "\" & fileName

            Dim oMail As EAGetMailObjLib.Mail
            Set oMail = oClient.GetMail(info)
            oMail.SaveAs fullFileName, True


            If leaveCopy Then
                ' Add the email uidl to uidl file to avoid we retrieve it next time.
                oUIDLManager.AddUIDL oServer, info.UIDL, fileName
            Else
                oClient.Delete info

                ' Remove UIDL from local uidl file.
                oUIDLManager.RemoveUIDL oServer, info.UIDL
            End If
        End If
    Next

    ' Quit
    oClient.Quit

    ' Update the uidl list to a text file and then we can load it next time.
    oUIDLManager.Update
    Exit Sub

ErrorHandle:

    MsgBox Err.Description
    If isUidlLoaded Then
        ' Update the uidl list to a text file and then we can load it next time.
        oUIDLManager.Update
    End If
End Sub

UIDL Manager

UIDLManager provides an easier way to maintain UIDL between your server and your local client. It stores UIDL collection to a local disk file and you can use this object to add, remove and search UIDL with this local file.

Work with UIDL Manager

VB6 - Retrieve unread/new email in IMAP4/EWS/WebDAV - example

Because IMAP/EWS/WebDAV support read mail flag, with this feature, we can also retrieve unread/new email only from IMAP4/EWS/WebDAV like this

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3
Const MailServerMsGraph = 4

Const GetMailInfos_All = 1
Const GetMailInfos_NewOnly = 2
Const GetMailInfos_ReadOnly = 4
Const GetMailInfos_SeqRange = 8
Const GetMailInfos_UIDRange = 16
Const GetMailInfos_PR_ENTRYID = 32
Const GetMailInfos_DateRange = 64
Const GetMailInfos_OrderByDateTime = 128

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim oServer As New EAGetMailObjLib.MailServer
    oServer.Server = "imap.emailarchitect.net"
    oServer.User = "test@emailarchitect.net"
    oServer.Password = "testpassword"
    oServer.Protocol = MailServerImap4

    ' Enable SSL/TLS connection, most modern email servers require SSL/TLS by default
    oServer.SSLConnection = True
    oServer.Port = 993

    ' If your IMAP doesn't deploy SSL connection
    ' Please use
    ' oServer.SSLConnection = False
    ' oServer.Port = 143

On Error GoTo ErrorHandle:
    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    ' retrieve unread/new email only
    oClient.GetMailInfosParam.Reset
    oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfos_NewOnly

    Dim infos As EAGetMailObjLib.MailInfoCollection
    Set infos = oClient.GetMailInfoList()
    MsgBox infos.Count & " unread emails"

    Dim i As Long
    For i = 0 To infos.Count - 1
        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos.Item(i)

        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        ' Receive email from IMAP4 server
        Dim oMail As EAGetMailObjLib.Mail
        Set oMail = oClient.GetMail(info)

        MsgBox "From: " & oMail.From.Address & _
            vbCrLf & "Subject: " & oMail.Subject

        Dim fileName As String
        ' Generate a random file name by current local datetime,
        ' You can use your method to generate the filename if you do not like it
        fileName = mailbox & "\" & oTools.GenFileName(i) & ".eml"

        ' Save email to local disk
        oMail.SaveAs fileName, True

         ' mark unread email as read, next time this email won't be retrieved again
        If Not info.Read Then
            oClient.MarkAsRead info, True
        End If

        ' if you don't want to leave a copy on server, please use
        ' oClient.Delete info
        ' instead of MarkAsRead
    Next

    ' Quit and expunge emails marked as deleted from IMAP4 server.
    oClient.Quit
    Exit Sub

ErrorHandle:
    MsgBox Err.Description
End Sub

32bit/x64 ActiveX DLL

Seperate builds of run-time dll for 32 and x64 platform

File Platform
Installation Path\Lib\native\x86\EAGetMailObj.dll 32 bit
Installation Path\Lib\native\x64\EAGetMailObj.dll 64 bit

Distribution

  • Standard EXE

    For VB6, C++, Delphi or other standard exe application, you can distribute EAGetMailObj.dll with your application to target machine without COM-registration and installer. To learn more detail, please have a look at Registration-free COM with Manifest File.

  • Script

    For ASP, VBScript, VBA, MS SQL Stored Procedure, you need to install EAGetMail on target machine by EAGetMail installer, both 32bit/x64 DLL are installed and registered.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.