Parse Non-Delivery Report (NDR) in VB.NET¶

Imports System.Data.SqlClient
Imports EAGetMail
Imports System.IO

Module Module1

    Sub Main(ByVal args() As String)
        If (args.Length < 1) Then
            Console.WriteLine("Usage: Parse_Reports.exe [email folder path]")
            Console.WriteLine("eg: Parse_Reports.exe ""c:\my folder""")
            Exit Sub
        End If

        Try
            ' change it to your sql server address, database, user and password
            ' The server/instance name syntax used in the server option is the same for all SQL Server connection strings.
            ' e.g.: Server=serveraddress\instancename;
            ' open database connection
            Dim oConn As New SqlConnection("Server=localhost;Database=myDB;User Id=myUser;Password=myPassword;")
            oConn.Open()

            Dim files() As String = Directory.GetFiles(args(0), "*.eml")
            Console.WriteLine("Total {0} email(s)", files.Length)
            Dim count As Integer = files.Length
            For i As Integer = 0 To count - 1

                Dim fileName As String = files(i)
                If (ParseEmail(fileName, oConn)) Then
                    ' Delete the local report file.
                    File.Delete(fileName)
                End If
            Next

            oConn.Close()

        Catch ep As Exception

            Console.WriteLine(ep.Message)
            Console.WriteLine(ep.StackTrace)
        End Try
    End Sub

    Function ParseEmail(ByVal fileName As String, ByRef oConn As SqlConnection)
        ParseEmail = False
        Dim oMail As New Mail("TryIt")
        oMail.Load(fileName, True)

        ' detect if this is a report or receipt
        If (Not oMail.IsReport) Then

            Console.WriteLine("Not a report or receipt!")
            Exit Function
        End If

        Dim oReport As MailReport = oMail.GetReport()
        ' we only process failure report
        If (oReport.ReportType <> DeliveryReportType.FailureReport) Then

            Console.WriteLine("Not a failure report!")
            Exit Function
        End If

        Console.WriteLine("OriginalRecipient: {0}", oReport.OriginalRecipient)
        Console.WriteLine("ErrorCode: {0}", oReport.ErrCode)
        Console.WriteLine("ErrorDesc: {0}", oReport.ErrDescription)
        Dim errorDesc As String = oReport.ErrDescription
        If (errorDesc.Length > 250) Then
            errorDesc = errorDesc.Substring(0, 250)
        End If

        ' INSERT the result to database.
        Dim sql As String = "INSERT INTO [dbo].[Failure_Report] " & _
            " ([address] " & _
            " ,[error_code] " & _
            " ,[error_desc] " & _
            " ,[error_datetime]) " & _
            " VALUES ( @address, @error_code, @error_desc, GETDATE())"

        Dim command As New SqlCommand(sql, oConn)
        command.Parameters.AddWithValue("@address", oReport.OriginalRecipient)
        command.Parameters.AddWithValue("@error_code", oReport.ErrCode)
        command.Parameters.AddWithValue("@error_desc", errorDesc)

        command.ExecuteNonQuery()
        command.Dispose()
        ParseEmail = True

    End Function

End Module